chore: Update provider URLs in providers.tf and add image pipeline mo…

…dules

image-pipeline.tf

@@ -0,0 +1,75 @@
+locals {
+  pipeline_repos = [
+    "image-pipeline-goss-testing",
+    "image-pipeline-ansible-playbooks",
+    "linux-image-pipeline",
+    "windows-image-pipeline"
+  ]
+}
+
+moved {
+  from = module.linux_image_pipeline
+  to   = module.image_pipeline["linux-image-pipeline"]
+}
+
+moved {
+  from = module.win_image_pipeline
+  to   = module.image_pipeline["windows-image-pipeline"]
+}
+
+moved {
+  from = module.goss-testing
+  to   = module.image_pipeline["image-pipeline-goss-testing"]
+}
+
+moved {
+  from = module.image_pipeline_ansible_playbooks
+  to   = module.image_pipeline["image-pipeline-ansible-playbooks"]
+}
+
+module "image_pipeline" {
+  for_each = toset(local.pipeline_repos)
+  source   = "git@github.e.it.census.gov:CSVD/terraform-github-repo"
+  #github_codeowners_team  = "CSVD"
+  github_repo_description = "Template repo for windows image pipelines"
+  repo_org                = "arnol377"
+  name                    = each.value
+  github_repo_topics = [
+    "terraform"
+  ]
+  force_name             = true
+  create_codeowners      = false
+  enforce_prs            = true
+  collaborators          = merge(local.collaborators, { garri325 = "admin" })
+  admin_teams            = [github_team.team.name]
+  pull_request_bypassers = local.pull_request_bypassers
+  extra_files = [
+    {
+      path = ".github/workflows/s3_upload.yml"
+      content = templatefile(
+        "${path.module}/workflow.yaml.tpl",
+        {
+          repo_name = each.value
+        }
+      )
+    }
+  ]
+}
+
+# image-pipeline-asset-releases
+module "asset_releases" {
+  source = "git@github.e.it.census.gov:CSVD/terraform-github-repo"
+  #github_codeowners_team  = "CSVD"
+  github_repo_description = "Terraform Workspace for publishing image-pipeline-assets"
+  repo_org                = "arnol377"
+  name                    = "image-pipeline-asset-releases"
+  github_repo_topics = [
+    "terraform"
+  ]
+  force_name             = true
+  create_codeowners      = false
+  enforce_prs            = false
+  collaborators          = local.collaborators
+  admin_teams            = [github_team.team.name]
+  pull_request_bypassers = local.pull_request_bypassers
+}